As I come back from just one day off, and have 300+ emails to sort through, I would love a plugin that would allow me to sort through all this email and clear it out.
Any recommended tools that:
1. Work with Outlook 2016/Offcie365
2. DOES NOT require a subscription. One time purchase and you're done.
3. DOES NOT phone home to make periodic license checks.
Any help greatly appreciated.
There WAS a great ap for this called GTDOA that went off the market. I tried to buy the rights and source code but the company who owns it was not interested in selling it to me. You can find links to download it. I do not recommend it because it is abandonware - I had to struggle a lot with it switching from fully functional software to an expired trialware (even though I purchased a license copy.)
Diane at SlipStick systems created a great Outlook macro here
https://forums.slipstick.com/threads/95521-gtd-netcentrics-add-in-for-2016/
I could not get this stock code to work and I made some modifications to it. Again, I tried to buy the rights to this from Diane but she refused as much of the code she found online. The way we left it was, for my modification, I can distribute it but not sell it.
What this code does - Every time you send an email, you get the option of creating a task or a calendar appointment or neither. If you choose to create a task or appointment, the script makes a copy of your sent email and pastes it in the task or appointment body and put in an HTML hyperlink to this sent message.
This code will not invoke unless you send an email. Thus, if you want a task from an incoming email that you did not reply to, you have to copy and paste the email manually.
Despite the shortcomings, this script along with some operating procedures work better than any of the plug-ins I have seen...and its free
Option Explicit
Dim strID As String, strLink As String, strLinkText As String
Private WithEvents olSentItems As Items
Private Sub Application_Startup()
Dim objNS As NameSpace
Set objNS = Application.Session
' instantiate objects declared WithEvents
Set olSentItems = objNS.GetDefaultFolder(olFolderSentMail).Items
Set objNS = Nothing
End Sub
Private Sub olSentItems_ItemAdd(ByVal Item As Object)
On Error Resume Next
Dim prompt As String
Dim oForward As MailItem
prompt$ = "Do you want to create a Task or Appointment for this message?"
If MsgBox(prompt$, vbYesNo + vbQuestion + vbMsgBoxSetForeground, "Create Task or Appointment?") = vbYes Then
strID = Item.EntryID
strLink = "outlook:" & strID
strLinkText = Item.Subject
CreateTaskForMessage Item
End If
End Sub
Sub CreateTaskForMessage(Item As MailItem)
Dim prompt As String
Dim objNewItem As Object
Dim objInsp As Outlook.Inspector
Dim oForward As MailItem
' Add reference to Word library
' in VBA Editor, Tools, References
Dim objDoc As Word.Document
Dim objWord As Word.Application
Dim objSel As Word.Selection
Dim oBookmark As Word.Bookmark
Dim Response
prompt$ = "Do you want to create a Task for this message?" & vbCrLf & "Choose Yes to create a Task." & vbCrLf & "Choose No to create an Appointment."
Response = MsgBox(prompt$, vbYesNoCancel + vbQuestion + vbMsgBoxSetForeground, "Create Task or Appointment?")
If Response = vbCancel Then Exit Sub
Set oForward = Item.Forward
oForward.Display
Set objInsp = oForward.GetInspector
If objInsp.EditorType = olEditorWord Then
Set objDoc = objInsp.WordEditor
Set objWord = objDoc.Application
'removes your signature from the top of the Forward
If objDoc.Bookmarks.Exists("_MailAutoSig") Then
Set oBookmark = objDoc.Bookmarks("_MailAutoSig")
oBookmark.Select
objDoc.Windows(1).Selection.Delete
End If
Set objSel = objWord.Selection
With objSel
.WholeStory
.Copy
End With
End If
oForward.Close olDiscard
If Response = vbYes Then
Set objNewItem = Application.CreateItem(olTaskItem)
' set task-only fields here
With objNewItem
.ReminderSet = False
.ReminderTime = DateSerial(Year(Now), Month(Now), Day(Now)) + #12:00:00 AM#
End With
Else
Set objNewItem = Application.CreateItem(olAppointmentItem)
'set appointment-only fields here
With objNewItem
.BodyFormat = olFormatHTML
.Start = DateSerial(Year(Now), Month(Now), Day(Now)) + #8:00:00 AM#
End With
End If
Set objInsp = objNewItem.GetInspector
Set objDoc = objInsp.WordEditor
Set objSel = objDoc.Windows(1).Selection
With objNewItem
.Subject = strLinkText
objSel.PasteAndFormat (wdFormatOriginalFormatting)
objSel.GoTo What:=wdGoToSection, Which:=wdGoToFirst
objDoc.Hyperlinks.Add objSel.Range, strLink, "", "", strLinkText, ""
objSel.Range.InsertBefore "Link to "
.Display
.Save
End With
End Sub
